Microsoft KB Archive/163530

Knowledge Base

OFF97: Sample VB Code to Count Graph 97 Objects on Current Slide

Article ID: 163530

Article Last Modified on 8/17/2005

---

APPLIES TO

• Microsoft Graph 97
• Microsoft Office 97 Standard Edition
• Microsoft PowerPoint 98 for Macintosh
• Microsoft PowerPoint 97 Standard Edition
• Microsoft Graph 98 Macintosh Edition

---

This article was previously published under Q163530

SUMMARY

This article contains a sample Microsoft Visual Basic for Applications macro (Sub procedure) that counts the embedded Microsoft Graph 8 objects on a Microsoft PowerPoint slide and then displays the total in a message box.

MORE INFORMATION

Microsoft provides programming examples for illustration only, without warranty either expressed or implied. This includes, but is not limited to, the implied warranties of merchantability or fitness for a particular purpose. This article assumes that you are familiar with the programming language that is being demonstrated and with the tools that are used to create and to debug procedures. Microsoft support engineers can help explain the functionality of a particular procedure, but they will not modify these examples to provide added functionality or construct procedures to meet your specific requirements. NOTE: This macro counts Graph 8 objects when you are using slide view.

Sample Visual Basic Procedure

Sub CountGraphs()

   ' Dimension the variables.
   Dim shapeObject As Shape
   Dim lSlideNumber As Long
   Dim lCount As Long
   Dim strPrompt As String
   Dim strTitle As String
   Dim lBoxStyle As Long

   ' Make sure PowerPoint is using slide view.
   If ActiveWindow.ViewType <> ppViewSlide Then

      MsgBox "You must be in slide view to run this macro."
      End

   End If

   ' Initialize the counter.
   lCount = 0

   ' Get the current slide number.
   lSlideNumber = ActiveWindow.Selection.SlideRange.SlideNumber

   ' Look at all shapes on the current slide.
   For Each shapeObject In _
      ActivePresentation.Slides(lSlideNumber).Shapes

      ' Check to see whether shape is an OLE object.
      If shapeObject.Type = msoEmbeddedOLEObject Then

         ' Check to see whether OLE object is Graph 8 object. The ProgID
         ' is case sensitive.
         If shapeObject.OLEFormat.ProgID = "MSGraph.Chart.8" Then

            ' Found a graph; add 1 to the total.
            lCount = lCount + 1
         End If

      End If

   Next shapeObject

   ' Creates and then displays the message box.

   ' Set the message box style.
   lBoxStyle = vbInformation

   Select Case lCount

      ' No graphs were found.
      Case 0
         strPrompt = "No graphs were found on the slide."
         strTitle = "No graphs"

      ' One graph was found.
      Case 1
         strPrompt = "One graph was found on the slide."
         strTitle = "One Graph"

      ' More than one graph was found.
      Case Is > 1
         strPrompt = lCount & " Graphs were found on the slide."
         strTitle = lCount & " Graphs"

      ' An error occurred.
      Case Else
         strPrompt = "An error occurred!"
         strTitle = "Error"
         lBoxStyle = vbCritical
   End Select

   'Display the message box.
   MsgBox strPrompt, lBoxStyle, strTitle

End Sub
                

REFERENCES

For more information about creating Visual Basic for Applications macros, click the Office Assistant in Microsoft PowerPoint, type "how to create a macro," click Search, and then click to view "Create a macro in Visual Basic Editor."

For more information about running Visual Basic for Applications macros, click the Office Assistant in Microsoft PowerPoint, type "how to run a macro," click Search, and then click to view "Run a macro."

NOTE: If the Assistant is hidden, click the Office Assistant button on the Standard toolbar. If the Assistant is not able to answer your query, please see the following article in the Microsoft Knowledge Base:

176476 OFF: Office Assistant Not Answering Visual Basic Questions

For more information about getting help with Visual Basic for Applications, please see the following article in the Microsoft Knowledge Base:

163435 VBA: Programming Resources for Visual Basic for Applications

Additional query words: 8.00 ppt8 vba vbe macppt mac_ppt ppt98 powerpt OFF97

Keywords: kbinfo kbmacro kbprogramming kbdtacode kbcode KB163530

---

Send feedback to Microsoft

© Microsoft Corporation. All rights reserved.