Microsoft KB Archive/940248

Knowledge Base

Error message when a user accesses a SharePoint Web site that is published in ISA Server 2006: "HTTP 401 Unauthorized"

Article ID: 940248

Article Last Modified on 8/14/2007

---

APPLIES TO

• Microsoft Internet Security and Acceleration Server 2006 Standard Edition
• Microsoft Internet Security and Acceleration Server 2006 Enterprise Edition

---

SYMPTOMS

When a user accesses a SharePoint Web site that is published in Microsoft Internet Security and Acceleration (ISA) Server 2006, the user receives the following error message:

HTTP 401 Unauthorized

This problem occurs when the following conditions are true:

• In the Web listener that the SharePoint Web publishing rule uses, the following authentication methods are configured:
  • HTML Form Authentication
  • LDAP (Active Directory)
• The Web client sends a POST request to the SharePoint Web site.
• The URL of the POST request contains extended characters. For example, the URL contains é, à, or è.

CAUSE

This problem occurs because ISA Server cannot parse a URL that contains extended characters. In this case, ISA Server rejects the POST request that the client sends.

RESOLUTION

To resolve this problem, follow these steps:

1. Apply the hotfix that is described in Microsoft Knowledge Base article 940250. For more information, click the following article number to view the article in the Microsoft Knowledge Base:

   940250 Description of the ISA Server 2006 hotfix package: July 16, 2007

2. Copy the following script into Notepad:

   Const SE_VPS_GUID = "{143F5698-103B-12D4-FF34-1F34767DEabc}"
   Const SE_VPS_NAME = "CookieFilterDecodeUEncoding"
   Const SE_VPS_VALUE = true
   
   Sub SetValue()
   
       ' Create the root obect.
       Dim root  ' The FPCLib.FPC root object
       Set root = CreateObject("FPC.Root")
   
       'Declare the other objects needed.
       Dim array       ' An FPCArray object
       Dim VendorSets  ' An FPCVendorParametersSets collection
       Dim VendorSet   ' An FPCVendorParametersSet object
   
       ' Get references to the array object
       ' and the network rules collection.
       Set array = root.GetContainingArray
       Set VendorSets = array.VendorParametersSets
   
       On Error Resume Next
       Set VendorSet = VendorSets.Item( SE_VPS_GUID )
   
       If Err.Number <> 0 Then
           Err.Clear
   
           ' Add the item
           Set VendorSet = VendorSets.Add( SE_VPS_GUID )
           CheckError
           WScript.Echo "New VendorSet added... " & VendorSet.Name
   
       Else
           WScript.Echo "Existing VendorSet found... value- " &  VendorSet.Value(SE_VPS_NAME)
       End If
   
       if VendorSet.Value(SE_VPS_NAME) <> SE_VPS_VALUE Then
   
           Err.Clear
           VendorSet.Value(SE_VPS_NAME) = SE_VPS_VALUE
   
           If Err.Number <> 0 Then
               CheckError
           Else
               VendorSets.Save false, true
               CheckError
   
               If Err.Number = 0 Then
                   WScript.Echo "Done with " & SE_VPS_NAME & ", saved!"
               End If
           End If
       Else
           WScript.Echo "Done with " & SE_VPS_NAME & ", no change!"
       End If
   
   End Sub
   
   Sub CheckError()
   
       If Err.Number <> 0 Then
           WScript.Echo "An error occurred: 0x" & Hex(Err.Number) & " " & Err.Description
           Err.Clear
       End If
   
   End Sub
   
   SetValue
   

3. Save the file as a Microsoft Visual Basic script file by using the .vbs file name extension. For example, save the file by using the following name:

   EnableKB940248.vbs

4. At a command prompt, move to the location where you saved the EnableKB940248.vbs file.
5. Run the following command:

   cscript EnableKB940248.vbs

Note After you follow these steps, only the query part of the URL can contain extended characters. The query part follows the question mark (?) in the URL. The part that comes before the question mark in the URL cannot contain extended characters even after you use this resolution.

STATUS

Microsoft has confirmed that this is a problem in the Microsoft products that are listed in the "Applies to" section.

Keywords: kbtshoot kbexpertiseinter kbprb KB940248

---

Send feedback to Microsoft

© Microsoft Corporation. All rights reserved.