Microsoft KB Archive/921944

Knowledge Base

A client computer takes longer than expected to connect to a Web site through an ISA Server 2004 Web proxy server

Article ID: 921944

Article Last Modified on 12/4/2007

---

APPLIES TO

• Microsoft Internet Security and Acceleration Server 2004 Enterprise Edition
• Microsoft Internet Security and Acceleration Server 2004 Standard Edition

---

SYMPTOMS

Consider the following scenario:

• A client computer tries to connect to a Web site through a Microsoft Internet Security and Acceleration (ISA) Server 2004-based Web proxy server.
• The ISA Server 2004-based Web proxy server is configured to request user authentication from client computers.
• The client computer uses the HTTP 1.0 protocol to send connection requests to the ISA Server 2004-based Web proxy server.

In this scenario, the client computer takes longer than expected to connect to the Web site.

CAUSE

This problem occurs because the client computer does not support connection requests that contain a "Proxy-Connection: Keep-Alive" header. By default, the ISA Server 2004-based Web proxy server keeps the connection alive by assuming that the client computer supports connection requests that contain the "Proxy-Connection: Keep-Alive" header.

If the client computer does not support connection requests that contain a "Proxy-Connection: Keep-Alive" header, the ISA Server 2004-based Web proxy server will close the connection after the connection times out. By default, the time-out is two minutes. Therefore, each connection request will take two extra minutes.

RESOLUTION

To resolve this problem, follow these steps:

1. On the ISA Server 2004-based computer, install the hotfix that is described in the following Microsoft Knowledge Base article:

   921937 Description of the ISA Server 2004 hotfix package: July 6, 2006

2. Run the following Microsoft Visual Basic script on the ISA Server 2004-based computer. To run this script, follow these steps:

   1. Copy the script to a text editor such as Notepad, and then save it to a file name that has a .vbs file name extension.
   2. Double-click the Visual Basic script file that you created in step 2a to run the script.

   Microsoft provides programming examples for illustration only, without warranty either expressed or implied. This includes, but is not limited to, the implied warranties of merchantability or fitness for a particular purpose. This article assumes that you are familiar with the programming language that is being demonstrated and with the tools that are used to create and to debug procedures. Microsoft support engineers can help explain the functionality of a particular procedure, but they will not modify these examples to provide added functionality or construct procedures to meet your specific requirements.

   '----Script begin
   Const SE_VPS_GUID = "{143F5698-103B-12D4-FF34-1F34767DEabc}"
   Const SE_VPS_VALUE = "DontKeepAliveAuthenticatedSession"
   
   Sub SetValue()
   
       ' Create the root obect.
       Dim root  ' The FPCLib.FPC root object
       Set root = CreateObject("FPC.Root")
   
       'Declare the other objects needed.
       Dim array       ' An FPCArray object
       Dim VendorSets  ' An FPCVendorParametersSets collection
       Dim VendorSet   ' An FPCVendorParametersSet object
   
       ' Get references to the array object
       ' and the network rules collection.
       Set array = root.GetContainingArray
       Set VendorSets = array.VendorParametersSets
   
       On Error Resume Next
       Set VendorSet = VendorSets.Item( SE_VPS_GUID )
   
       If Err.Number <> 0 Then
           Err.Clear
   
           ' Add the item
           Set VendorSet = VendorSets.Add( SE_VPS_GUID )
           CheckError
           WScript.Echo "New VendorSet added... " & VendorSet.Name
   
       Else
           WScript.Echo "Existing VendorSet found... value- " &  VendorSet.Value(SE_VPS_VALUE)
       End If
   
       if VendorSet.Value(SE_VPS_VALUE) <> true Then
   
           Err.Clear
           VendorSet.Value(SE_VPS_VALUE) = true
   
           If Err.Number <> 0 Then
               CheckError
           Else
               VendorSets.Save false, true
               CheckError
   
               If Err.Number = 0 Then
                   WScript.Echo "Done with " & SE_VPS_VALUE & ", saved!"
               End If
           End If
       Else
           WScript.Echo "Done with " & SE_VPS_VALUE & ", no change!"
       End If
   
   End Sub
   
   Sub CheckError()
   
       If Err.Number <> 0 Then
           WScript.Echo "An error occurred: 0x" & Hex(Err.Number) & " " & Err.Description
           Err.Clear
       End If
   
   End Sub
   
   SetValue
   
   '----Script end

Keywords: kbtshoot KB921944

---

Send feedback to Microsoft

© Microsoft Corporation. All rights reserved.