Microsoft KB Archive/915025

Knowledge Base

You cannot cache HTTP content on a downstream server that is running ISA Server 2004

Article ID: 915025

Article Last Modified on 12/4/2007

---

APPLIES TO

• Microsoft Internet Security and Acceleration Server 2004 Enterprise Edition
• Microsoft Internet Security and Acceleration Server 2004 Standard Edition

---

SYMPTOMS

Consider the following scenario:

• You have a downstream server that is running Microsoft Internet Security and Acceleration (ISA) Server 2004.
• You try to cache HTTP content on this server.
• An upstream proxy server is configured to request client authentication.

In this scenario, you cannot cache HTTP content on the downstream server.

CAUSE

By design, the downstream ISA Server computer does not cache content if the upstream proxy server is configured to request client authentication.

RESOLUTION

To resolve this problem, obtain the latest service pack for ISA Server 2004. For more information, click the following article number to view the article in the Microsoft Knowledge Base:

891024 How to obtain the latest ISA Server 2004 service pack

STATUS

Microsoft has confirmed that this is a problem in the Microsoft products that are listed in the "Applies to" section.

MORE INFORMATION

After you install ISA Server 2004 Service Pack 2 (SP2), you can configure the downstream ISA Server computer to cache content even if the upstream proxy server is configured to request client authentication. To configure the downstream ISA Server computer to cache content, change the DontMarkSessionAsPrivateIfProxyAuthSeen parameter. To do this, follow these steps.

Note The DontMarkSessionAsPrivateIfProxyAuthSeen parameter is the name of a vendor parameter set that can be modified after you install ISA Server 2004 SP2.

1. Copy and paste the following code into Notepad:

   Sub AddDontMarkSessionAsPrivateIfProxyAuthSeen()
   
   ' Create the root object.
   Dim root ' The FPCLib.FPC root object
   Set root = CreateObject("FPC.Root")
   
   ' Declare the other objects that are required.
   Dim array ' An FPCArray object
   Dim VendorSets ' An FPCVendorParametersSets collection
   Dim VendorSet ' An FPCVendorParametersSet object
   
   ' Obtain references to the array object
   ' and to the network rules collection.
   Set array = root.GetContainingArray
   Set VendorSets = array.VendorParametersSets
   
   On Error Resume Next
   Set VendorSet = VendorSets.Item( "{143F5698-103B-12D4-FF34-1F34767DEabc}" )
   
   If Err.Number <> 0 Then
   Err.Clear
   
   ' Add the item.
   Set VendorSet = VendorSets.Add( "{143F5698-103B-12D4-FF34-1F34767DEabc}" )
   CheckError
   WScript.Echo "New VendorSet added... " & VendorSet.Name
   
   Else
   WScript.Echo "Existing VendorSet found... value- " & VendorSet.Value("DontMarkSessionAsPrivateIfProxyAuthSeen")
   End If
   
   if VendorSet.Value("DontMarkSessionAsPrivateIfProxyAuthSeen") <> 1 Then
   
   Err.Clear
   VendorSet.Value("DontMarkSessionAsPrivateIfProxyAuthSeen") = 1
   
   If Err.Number <> 0 Then
   CheckError
   Else
   VendorSets.Save false, true
   CheckError
   
   If Err.Number = 0 Then
   WScript.Echo "Done, saved!"
   End If
   End If
   Else
   WScript.Echo "Done, no change!"
   End If
   
   End Sub
   
   Sub CheckError()
   
   If Err.Number <> 0 Then
   WScript.Echo "An error occurred: 0x" & Hex(Err.Number) & " " & Err.Description
   Err.Clear
   End If
   
   End Sub
   
   AddDontMarkSessionAsPrivateIfProxyAuthSeen

2. Save the file as "DownstreamISAcacheContent.vbs."
3. To run the code, type the following command at a command prompt:

   cscript. DownstreamISAcacheContent.vbs

   Note You must run the code from the same location in which you saved the DownstreamISAcacheContent.vbs file in step 2.

Notes

• This code sets the DontMarkSessionAsPrivateIfProxyAuthSeen parameter to a value of 1. This value enables the downstream ISA Server computer to cache content even if the upstream proxy server is configured to request client authentication.
• If you select the Content requiring user authentication for retrieval option when you create a cache rule in ISA Server 2004, the downstream ISA Server computer caches content from the upstream proxy server. The downstream server also caches content that is authenticated by any server, such as by a Web server.

For more information about the standard terminology that is used to describe Microsoft software updates, click the following article number to view the article in the Microsoft Knowledge Base:

824684 Description of the standard terminology that is used to describe Microsoft software updates

Keywords: kbbug kbfix kbqfe kbpubtypekc KB915025

---

Send feedback to Microsoft

© Microsoft Corporation. All rights reserved.