Knowledge Base

The dial-up connection to a remote network is continually dialed when a client computer makes a request for a URL that is not defined in any LDT in ISA Server 2004

Article ID: 901109

Article Last Modified on 12/4/2007

APPLIES TO

Microsoft Internet Security and Acceleration Server 2004 Enterprise Edition
Microsoft Internet Security and Acceleration Server 2004 Standard Edition

SYMPTOMS

In Microsoft Internet Security and Acceleration (ISA) Server 2004, when a client computer makes a request for a URL that is not defined in any Local Domain Table (LDT), the dial-up connection to a remote network is continually dialed if a Dial on Demand connection is configured to connect to a remote network.

Notes

ISA Server 2004 does not usually have to dial the remote network for Internet URLs.
ISA Server 2004 should only dial the remote network if the requested URL is in the LDT for the remote network or if a requested Internet Protocol (IP) address matches the IP address of the remote network.

CAUSE

This problem occurs because ISA Server 2004 does not know whether to use a DNS server on the remote network to resolve the requested URL. Therefore, ISA Server 2004 dials the remote network to determine whether there is an available DNS server for the requested URL.

RESOLUTION

Service pack information

To resolve this problem, obtain the latest service pack for Internet Security and Acceleration Server 2004. For more information, click the following article number to view the article in the Microsoft Knowledge Base:

891024 How to obtain the latest ISA Server 2004 service pack

Hotfix Information

Hotfix information

A supported hotfix is now available from Microsoft. However, this hotfix is intended to correct only the problem that is described in this article. Apply this hotfix only to systems that are experiencing this specific problem. This hotfix might receive additional testing. Therefore, if you are not severely affected by this problem, we recommend that you wait for the next service pack that contains this hotfix.

To resolve this problem, submit a request to Microsoft Online Customer Services to obtain the hotfix. To submit an online request to obtain the hotfix, visit the following Microsoft Web site:

http://go.microsoft.com/?linkid=6294451

Note If additional issues occur or any troubleshooting is required, you might have to create a separate service request. The usual support costs will apply to additional support questions and issues that do not qualify for this specific hotfix. To create a separate service request, visit the following Microsoft Web site:

http://support.microsoft.com/contactus/?ws=support

Prerequisites

To apply this hotfix on an ISA Server 2004, Standard Edition-based computer, you must have ISA Server 2004 Service Pack 1 (SP1) installed. For more information, click the following article number to view the article in the Microsoft Knowledge Base:

891024 How to obtain the latest ISA Server 2004 service pack

Restart requirement

If you are prompted to restart the computer, you must restart the computer after you apply this hotfix.

Hotfix replacement information

This hotfix does not replace any other hotfixes.

File information

The English version of this hotfix has the file attributes (or later file attributes) that are listed in the following table. The dates and times for these files are listed in Coordinated Universal Time (UTC). When you view the file information, it is converted to local time. To find the difference between UTC and local time, use the Time Zone tab in the Date and Time tool in Control Panel.

   Date         Time   Version          Size  File name
   ------------------------------------------------------
   05-Jun-2005  07:32  4.0.2163.271  365,792  Msphlpr.dll

After you apply the hotfix

After you apply the hotfix that is described in this article, enable the DontDialToGetADnsServer flag. When this flag is enabled, the connection will not be dialed if the requested URL is not defined in any LDT.

To enable the DontDialToGetADnsServer flag, use the following script:

Sub AddHotFixVPSValue(ValueName , Mode)

    ' Create the root obect.
    Dim root  ' The FPCLib.FPC root object
    Set root = CreateObject("FPC.Root")


   'Declare the other objects needed.
    Dim array       ' An FPCArray object
    Dim VendorSets  ' An FPCVendorParametersSets collection
    Dim VendorSet   ' An FPCVendorParametersSet object

    ' Get references to the array object and the network rules collection.
    Set array = root.GetContainingArray
    Set VendorSets = array.VendorParametersSets

 
    On Error Resume Next
    Set VendorSet = VendorSets.Item( "{143F5698-103B-12D4-FF34-1F34767DEabc}" )
    
    If Err.Number <> 0 Then
        Err.Clear
    if Mode= true then
            ' Add the item
            Set VendorSet = VendorSets.Add( "{143F5698-103B-12D4-FF34-1F34767DEabc}" )
            CheckError
            WScript.Echo "New VendorSet added... " & VendorSet.Name
    else
        WScript.Echo "VendorSet {143F5698-103B-12D4-FF34-1F34767DEabc} doesn't exist, no need to disable"
        WScript.Quit
    end if
    Else
        WScript.Echo "Existing VendorSet found... " & ValueName & "=" &  VendorSet.Value(ValueName)
    End If

    if VendorSet.Value(ValueName) <> mode then
            Err.Clear
        VendorSet.Value(ValueName) = mode
        If Err.Number <> 0 Then
            CheckError
        Else
        VendorSets.Save false, true
        CheckError
            If Err.Number = 0 Then
                WScript.Echo "Saved - " & ValueName & "=" &  VendorSet.Value(ValueName) 
            End If
        End If
    Else 
        WScript.Echo ValueName & "=" &  VendorSet.Value(ValueName) & ",No change needed!"
    End If
End Sub


Sub CheckError()
    If Err.Number <> 0 Then
        WScript.Echo "An error occurred: 0x" & Hex(Err.Number) & " " & Err.Description
        Err.Clear
    End If
End Sub


'main
Dim args,FlagName,Mode 
Set args = Wscript.Arguments
if args.Count < 2 then 
    WScript.echo "This script sets a VPS flag for ISA2004 hotfixes"
    WScript.echo "Usage: AddHotFixVPSValue <Flag Name> <DISABLE/ENABLE>"
    WScript.echo "Examples:"
    wscript.echo "To set the flag DontDialToGetADnsServer run: "
    WScript.echo  "     AddHotFixVPSValue DontDialToGetADnsServer ENABLE"
    WScript.echo "To disable the flag run: "
    WScript.echo "      AddHotFixVPSValue DontDialToGetADnsServer DISABLE"
    WScript.Quit
end if

'Parse Command line
FlagName = args(0)
select case UCASE(args(1))
case "DISABLE" 
    Mode =false
case "ENABLE"
    Mode = true
case else
    WScript.echo "Second parameter should be ENABLE/DISABLE"
    WScript.Quit
End select

AddHotFixVPSValue FlagName, Mode

STATUS

Microsoft has confirmed that this is a problem in the Microsoft products that are listed in the "Applies to" section. This problem was first corrected in Internet Security and Acceleration Server 2004 Service Pack 2.

MORE INFORMATION

For more information, click the following article number to view the article in the Microsoft Knowledge Base:

885957 How to install ISA Server hotfixes and updates