Article ID: 212572
Article Last Modified on 10/11/2006
APPLIES TO
- Microsoft Word 2000 Standard Edition
This article was previously published under Q212572
SYMPTOMS
When your Visual Basic for Applications macro creates an object variable that is set to reference a picture object, and if your macro later anchors a hyperlink to that same picture object, the object reference is deleted, and the following error message appears:
NOTE: The object itself remains. Only the object reference is deleted from the document.
For example, the following Visual Basic for Applications macro adds a hyperlink to an already linked picture. The hyperlink is "anchored" to the picture object that is referenced by the InLine Picture object variable oILPic. After the hyperlink is added, the object variable reference oILPic is deleted.
Sub DoInLineShapeHyperlink()
Dim oDoc As Document
Dim oILPic As InlineShape
Dim oHLink As Hyperlink
Dim sPicFile As String
Dim sLinkFile as String
' Specify an actual graphic and hyperlink
sPicFile = "<Insert your Graphic File Path and Name here>"
sLinkFile = "<Insert a valid HyperLink Path here>"
' Create new document.
Set oDoc = Documents.Add
' Insert a picture.
Set oILPic = oDoc.InlineShapes.AddPicture _
(Range:=oDoc.Content, FileName:=sPicFile, LinkToFile:=True)
' Add a hyperlink for the picture.
oDoc.Hyperlinks.Add Anchor:=oILPic.Range, Address:=sLinkFile
' The error occurs here because oILPic is no longer valid.
Set oHLink = oILPic.Hyperlink
End Sub
CAUSE
The "Object has been deleted" error message appears because the macro has attempted to access an object that has been deleted (oILPic in the example in the "Symptoms" section of this article). The object may have been deleted deliberately, such as with the Delete method, or it may have been deleted as a side effect of another operation. An example of this is when a frame is added around an inline shape. The original inline shape is deleted, and a copy of the shape is created inside the frame.
WORKAROUND
Microsoft provides programming examples for illustration only, without warranty either expressed or implied. This includes, but is not limited to, the implied warranties of merchantability or fitness for a particular purpose. This article assumes that you are familiar with the programming language that is being demonstrated and with the tools that are used to create and to debug procedures. Microsoft support engineers can help explain the functionality of a particular procedure, but they will not modify these examples to provide added functionality or construct procedures to meet your specific requirements.
For more information about how to use the sample code in this article, click the article number below to view the article in the Microsoft Knowledge Base:
212536 OFF2000: How to Run Sample Code from Knowledge Base Articles
To work around this problem, reference the object directly, as in the following example:
Private Sub DoInLineShapeHyperlink()
Dim oDoc As Document
Dim oILPic As InlineShape
Dim oHLink As Hyperlink
Dim sPicFile As String
Dim sLinkFile as String
' Specify an actual graphic and hyperlink
sPicFile = "<Insert your Graphic File Path and Name here>"
sLinkFile = "<Insert a valid HyperLink Path here>"
' Create new document.
Set oDoc = Documents.Add
' Insert a picture.
Set oILPic = oDoc.InlineShapes.AddPicture _
(Range:=oDoc.Content, FileName:= sPicFile, LinkToFile:=True)
' Add a hyperlink for the picture.
oDoc.Hyperlinks.Add Anchor:=oILPic.Range, Address:=sLinkFile
' Use the InlineShapes Property to reference the object.
Set oHLink = oDoc.InlineShapes(1).Hyperlink
End Sub
MORE INFORMATION
You can use the IsObjectValid method to verify that an object still exists. The following example demonstrates the use of this method:
Sub testObject()
Dim ilShp As InlineShape
Set ilShp = ActiveDocument.InlineShapes.AddPicture _
("<Insert your Graphic File Path and Name here>")
MsgBox IsObjectValid(ilShp) ' This will display True
ilShp.Delete
MsgBox IsObjectValid(ilShp) ' This will display False
End Sub
REFERENCES
For additional information about getting help with Visual Basic for Applications, click the article numbers below to view the articles in the Microsoft Knowledge Base:
212623 WD2000: Macro Programming Resources
226118 OFF2000: Programming Resources for Visual Basic for Applications
Additional query words: vb vba vbe editor
Keywords: kbbug kberrmsg kbmacroexample kbnofix kbprogramming kbusage KB212572
