Knowledge Base

ACC2000: How to Programmatically Display a Help File

Article ID: 209843

Article Last Modified on 10/11/2006

APPLIES TO

Microsoft Access 2000 Standard Edition

This article was previously published under Q209843

Advanced: Requires expert coding, interoperability, and multiuser skills.

This article applies to a Microsoft Access database (.mdb) and to a Microsoft Access project (.adp).

SUMMARY

This article shows you three techniques that you can use to programmatically display a Help file.

MORE INFORMATION

Microsoft provides programming examples for illustration only, without warranty either expressed or implied. This includes, but is not limited to, the implied warranties of merchantability or fitness for a particular purpose. This article assumes that you are familiar with the programming language that is being demonstrated and with the tools that are used to create and to debug procedures. Microsoft support engineers can help explain the functionality of a particular procedure, but they will not modify these examples to provide added functionality or construct procedures to meet your specific requirements.

Method 1

You can use the Shell command to display a Help file. To do so, follow these steps:

Create a new form.
Add a command button to the form.

In the Click event of the command button, type one of the following two lines of code:

Shell "Winhlp32.exe C:\Windows\Help\Access.hlp", vbNormalFocus

or

Shell "HH.exe C:\Windows\Help\Access.chm", vbNormalFocus

NOTE: You should verify the name and path to the Help file that you want to use.

Method 2

When you run the code in Method 1 for the first time, the form will most likely open on the Contents tab of the Help file. However, if you then switch to the Index tab, close the Help file, and run the code again, the Index tab will be displayed. Whichever tab was last active is displayed each time that you run the code.

If you have Microsoft Office 2000 Developer, you can avoid this behavior by using the Common Dialog control. To do so, follow these steps:

On a new form, click ActiveX Control on the Insert menu.
In the Insert ActiveX Control dialog box, select the Microsoft Common Dialogs Control, version 6.0, and click OK. Microsoft Access should give it the name ActiveXCtl0.
Add a command button to the form.

Type the following code for the Click event of the command button:

With ActiveXCtl0    'Refers to the common dialog control.
    .HelpFile = "C:\Windows\System\Calc.hlp"
    .HelpCommand = 15
    .ShowHelp
End With

View the form in Form view and click the button. The Contents tab appears.
Switch to the Index tab, and then close the Help file.
Click the button again. Note that the Contents tab re-appears. The Help file does not open with the Index tab active.

NOTE: If you change the value assigned to .HelpCommand from 15 to 11, you should get the same results as when using the Shell command to open the Help file.

Method 3

A more powerful way to display a Help file is to use Microsoft Windows API calls. These require some functions that you must first type into a module. To do so, open a new module, and type the following code. (Descriptions of how to use each of these API functions appear at the end of this article.)

NOTE: You may have some Microsoft Windows API functions defined in an existing Microsoft Access library; therefore, your declarations may be duplicates. If you receive a duplicate procedure name error message, remove or comment out the declarations statement in your code.

Option Compare Database
Option Explicit

Public Const HELP_CONTEXT = &H1         'Display topic for Help context ID.
Public Const HELP_QUIT = &H2            'Terminate Help.
Public Const HELP_INDEX = &H3           'Display Help index.
Public Const HELP_CONTEXTPOPUP = &H8&   'Display Help context as a pop-up
                                        'window.
Public Const HELP_FINDER = &HB&         'If found, Display container file.
Public Const HELP_KEY = &H101           'Display topic for keyword.

'Declare the WinHelp function.
Declare Sub WinHelp Lib "user32" Alias "WinHelpA" (ByVal Hwnd As Long, _
    ByVal lpHelpFile As String, ByVal wCommand As Long, _
    ByVal dwData As Any)

Function OpenHelpContainer(ByVal strHelpFileName As String)
    'Opens the Help container.
    WinHelp Application.hWndAccessApp, ByVal strHelpFileName, _
        HELP_FINDER, ByVal vbNullString
End Function

Function OpenHelpIndex(ByVal strHelpFileName As String)
    'Opens the Help index.
    WinHelp Application.hWndAccessApp, ByVal strHelpFileName, HELP_KEY, _
        ByVal ""
End Function

Function OpenHelpIndexWithSearchKey(ByVal strHelpFileName As String, _
        ByVal strSearchKey As String)
    'Opens the Help index and searches for keyword SKey.
    WinHelp Application.hWndAccessApp, ByVal strHelpFileName, HELP_KEY, _
        ByVal strSearchKey
End Function

Function OpenHelpWithContextID(ByVal strHelpFileName As String, _
        lngContextID As Long)
    'Opens the Help file to ContextID.
    WinHelp Application.hWndAccessApp, ByVal strHelpFileName, _
        HELP_CONTEXT, ByVal lngContextID
End Function

Function OpenHelpWithContextIDPopup(ByVal strHelpFileName As String, _
        lngContextID As Long)
    'Opens the Help file to ContextID as a pop-up window.
    WinHelp Application.hWndAccessApp, ByVal strHelpFileName, _
        HELP_CONTEXTPOPUP, ByVal lngContextID
End Function

Function CloseHelpContainer(ByVal strHelpFileName As String)
    'Closes the specified Help file.
    WinHelp Application.hWndAccessApp, ByVal strHelpFileName, HELP_QUIT, _
        ByVal vbNullString
End Function

The above code provides some useful functions for displaying Help files. The list below describes the purpose of each.

NOTE: The following examples use the Help file "Calc.hlp", because it is usually in the System folder, and does not require a complete path.

OpenHelpContainer()
You can use the OpenHelpContainer function simply to open a Help file. To test this function, type the following in the Immediate window, and then press ENTER:
```
?OpenHelpContainer("Calc.hlp")
                        
```
This opens the Help file for the Microsoft Windows Calculator.
OpenHelpIndex()
Opens the Help file with the Index tab activated. To test this function, type the following in the Immediate window, and then press ENTER:
```
?OpenHelpIndex("Calc.hlp")
                        
```
This opens the Help file for the Microsoft Windows Calculator with the Index tab displayed.
OpenHelpIndexWithSearchKey()
Opens the specified Help index and searches for a keyword. To test this function, type the following in the Immediate window, and then press ENTER:
```
?OpenHelpIndexWithSearchKey("calc.hlp","simple calculations")
                        
```
Note that the "Simple Calculations" topic ID is displayed.
OpenHelpWithContextID()
Opens the Help file to a specified ContextID. To test this function, type the following in the Immediate window, and then press ENTER:
```
?OpenHelpWithContextID("calc.hlp",90)
                        
```
Note that it opens Help for the division button.
OpenHelpWithContextIDPopup()
Opens the Help file to a specified ContextID as a pop-up window. To test this function, type the following in the Immediate window, and then press ENTER:
```
?OpenHelpWithContextIDPopup("Calc.hlp",90)
                        
```
Note that it opens Help for the division button in a pop-up window.
CloseHelpContainer()
Closes the Help file. To test this function, type the following in the Immediate window, and then press ENTER:
```
?CloseHelpContainer("Calc.hlp")
                        
```
This should close the Microsoft Windows Calculator Help file if it is open.

REFERENCES

For more information about getting help with Visual Basic for Applications, please see the following article in the Microsoft Knowledge Base:

226118 OFF2000: Programming Resources for Visual Basic for Applications

Keywords: kbhowto kbprogramming KB209843