Microsoft KB Archive/183521

Knowledge Base

XL97: Custom Toolbar Added Above Existing Toolbars

Article ID: 183521

Article Last Modified on 6/17/2005

---

APPLIES TO

• Microsoft Excel 98 for Macintosh

---

This article was previously published under Q183521

SYMPTOMS

When you display a custom toolbar by using a Visual Basic for Applications macro, and you specify the constant xlTop for the Position property of the toolbar, the toolbar is added above toolbars that are docked at the top of the Microsoft Excel window.

In earlier versions of Microsoft Excel, if you specify the xlTop constant for the Position property of a toolbar, the toolbar is added immediately after the last toolbar that is docked at the top of the Microsoft Excel window.

WORKAROUND

To produce the behavior that occurs in earlier versions of Microsoft Excel, use the CommandBars object to create custom toolbars.

Microsoft provides programming examples for illustration only, without warranty either expressed or implied. This includes, but is not limited to, the implied warranties of merchantability or fitness for a particular purpose. This article assumes that you are familiar with the programming language that is being demonstrated and with the tools that are used to create and to debug procedures. Microsoft support engineers can help explain the functionality of a particular procedure, but they will not modify these examples to provide added functionality or construct procedures to meet your specific requirements.

Example

In the following example, a new toolbar is created by using the CommandBars object model. The new toolbar is positioned immediately after the last toolbar docked at the top of the Microsoft Excel window. To use this example, follow these steps:

1. Close and save any open workbooks, and then create a new workbook.
2. Start the Visual Basic Editor (press OPTION+F11).
3. On the Insert menu, click Module.

4. In the Visual Basic module window, type the following code:

   Sub AddToolbar()
   
            Dim NewBar As CommandBar
            Dim x As CommandBar, LastBar As CommandBar
            Dim LastRow As Integer
   
            ' The following loop goes through all toolbars.
            ' to determine which is the last toolbar docked
            ' at the top of the Microsoft Excel window.
            For Each x In Application.CommandBars
               If x.Visible = True And x.Position = msoBarTop Then
                  If x.RowIndex > LastRow Then
                     Set LastBar = x
                     LastRow = x.RowIndex
                  End If
               End If
            Next x
   
            ' Create a new toolbar.
            Set NewBar = CommandBars.Add(Name:="NewCmdBar")
   
            With NewBar
               ' Add a button to the toolbar.
               .Controls.Add Type:=msoControlButton, Id:=270
   
               ' Dock the toolbar at the top of the Microsoft Excel window.
               .Position = msoBarTop
   
               ' Set the leftmost position of the toolbar.
               .Left = LastBar.Left + LastBar.Width + 1
   
               ' Place the toolbar in the correct row.
               .RowIndex = LastRow
   
               ' Display the toolbar.
               .Visible = True
            End With
   
         End Sub
                           

5. Switch back to Microsoft Excel (press OPTION+F11).
6. Run the AddToolbar subroutine.

Creating a Reference to the Library

Before you run the AddToolbar subroutine, you must reference the Microsoft Office 8.0 Object Library. To do this, follow these steps:

1. Click the module sheet.
2. On the Tools menu, click References.
3. Click to select the Microsoft Office 8.0 Object Library check box and click OK.

STATUS

Microsoft has confirmed this to be a problem in the Microsoft products listed at the beginning of this article. We are researching this problem and will post new information here in the Microsoft Knowledge Base as it becomes available.

REFERENCES

For more information about creating command bars, click the Office Assistant in the Visual Basic Editor, type commandbars, click Search, and then click to view "Using command bars."

NOTE: If the Assistant is hidden, click the Office Assistant button on the Standard toolbar. If Microsoft Help is not installed on your computer, please see the following article in the Microsoft Knowledge Base:

176476 OFF: Office Assistant Not Answering Visual Basic Questions

Additional query words: XL98

Keywords: kbbug kbpending KB183521

---

Send feedback to Microsoft

© Microsoft Corporation. All rights reserved.