Microsoft KB Archive/222481

From BetaArchive Wiki
Knowledge Base


OL2000: How to Properly Reference Members of a Collection

Article ID: 222481

Article Last Modified on 11/23/2006



APPLIES TO

  • Microsoft Outlook 2000 Standard Edition



This article was previously published under Q222481


SUMMARY

If you use Visual Basic, Visual Basic for Applications, or Visual Basic Scripting Edition (VBScript) to loop through items in a folder, you may see the modifications to those items are not saved. You may be unintentionally retrieving the item again from the Items collection, and any changes that you have made to an item are unexpectedly lost.

MORE INFORMATION

Microsoft provides programming examples for illustration only, without warranty either expressed or implied, including, but not limited to, the implied warranties of merchantability and/or fitness for a particular purpose. This article assumes that you are familiar with the programming language being demonstrated and the tools used to create and debug procedures. Microsoft support professionals can help explain the functionality of a particular procedure, but they will not modify these examples to provide added functionality or construct procedures to meet your specific needs. If you have limited programming experience, you may want to contact a Microsoft Certified Partner or the Microsoft fee-based consulting line at (800) 936-5200. For more information about Microsoft Certified Partners, please visit the following Microsoft Web site:

For more information about the support options that are available and about how to contact Microsoft, visit the following Microsoft Web site:

Many Outlook solutions modify the contents of items in a folder. In most scenarios you loop through the Items collection in the Outlook object model. If you do not properly reference the items in the collection, you may receive unexpected results.

Before modifying an item and saving it, you should set an object variable to the item, make changes to the item using the object variable, and then save the object.

NOTE: Be sure to reference the Microsoft Outlook 9.0 Object Library before running these code examples and be aware running this code will modify any existing contacts you have in your Contacts folder.

Consider the following Visual Basic automation code sample that is designed to reset the birthday field for each contact in the default Contacts folder:

Sub ResetBirthdays1()
   Dim olns as Outlook.Namespace
   Dim oConItems As Outlook.Items
   Dim iNumItems As Integer
   Set ol = New Outlook.Application
   Set olns = ol.GetNamespace("MAPI")
   Set oConItems = olns.GetDefaultFolder(olFolderContacts).Items
   iNumItems = oConItems.Count
   For I = 1 to iNumItems
      oConItems.Item(I).Birthday = "1/1/4501"
      oConItems.Item(I).Close olSave
   Next
   Set oConItems = Nothing
   Set olns = Nothing
   Set ol = Nothing
End Sub
                

In the previous example, the loop is adequately structured and will process all of the items in the folder. However, within the loop each time ConItems.Item(I) is executed, it retrieves the specific item from the collection of items. In this case, the Birthday is set for an item, but then then following line of code gets the item from the collection again. The end result is that an unmodified item is saved.

The following example is one way of modifying the previous code sample so that it executes as expected:

Sub ResetBirthdays2()
   Dim olns As Outlook.Namespace
   Dim oConItems As Outlook.Items
   Dim iNumItems As Integer
   Set ol = New Outlook.Application
   Set olns = ol.GetNamespace("MAPI")
   Set oConItems = olns.GetDefaultFolder(olFolderContacts).Items
   iNumItems = oConItems.Count
   For I = 1 to iNumItems
      Set oCurItem = oConItems.Item(I)
      oCurItem.Birthday = "1/1/4501"
      oCurItem.Close olSave
   Next
   Set oConItems = Nothing
   Set olns = Nothing
   Set ol = Nothing
End Sub
                

In the previous sample, oCurItem is set to a specific item in the collection, modifications to the item are made using that object variable, and the object is saved. This avoids getting an item from the collection and losing any changes.

The following example provides the same functionality as the previous example, but uses the For Each...Next structure to loop through the items:

Sub ResetBirthdays3()
   Dim olns as Outlook.Namespace
   Dim oConItems As Outlook.Items
   Set ol = New Outlook.Application
   Set olns = ol.GetNamespace("MAPI")
   Set oConItems = olns.GetDefaultFolder(olFolderContacts).Items
   For Each oCurItem in oConItems
      oCurItem.Birthday = "1/1/4501"
      oCurItem.Close olSave
   Next
   Set oConItems = Nothing
   Set olns = Nothing
   Set ol = Nothing
End Sub
                

REFERENCES

For additional information about available resources and answers to commonly asked questions about Microsoft Outlook 2000 solutions, please see the following article in the Microsoft Knowledge Base:

146636 OL2000: Questions About Custom Forms and Outlook Solutions



Additional query words: OutSol OutSol2000

Keywords: kbhowto kbprogramming KB222481