Knowledge Base

How to retain information typed into a form field when you protect a form

Article ID: 191028

Article Last Modified on 1/23/2007

APPLIES TO

Microsoft Office Word 2003
Microsoft Word 2002 Standard Edition
Microsoft Word 2000 Standard Edition

This article was previously published under Q191028

SUMMARY

This article describes methods that allow you to do the following:

Retain information you type into a form field when you protect a form.
Unprotect a forms document, perform a spelling check, and retain information in the form fields when you reprotect the form.

MORE INFORMATION

Microsoft provides programming examples for illustration only, without warranty either expressed or implied. This includes, but is not limited to, the implied warranties of merchantability or fitness for a particular purpose. This article assumes that you are familiar with the programming language that is being demonstrated and with the tools that are used to create and to debug procedures. Microsoft support engineers can help explain the functionality of a particular procedure, but they will not modify these examples to provide added functionality or construct procedures to meet your specific requirements.
For additional information about how to use the sample code in this article, click the following article numbers to view the articles in the Microsoft Knowledge Base:

290140 How to run the sample code for the Office XP programs from Knowledge Base articles

212536 How to run sample code from Knowledge Base articles in Office 2000

Method 1: Alter the Protect/Unprotect Command Functionality

The following Microsoft Visual Basic for Applications macros (Sub procedures) protect your form without causing you to lose the text that you entered into a form field. The macros can be stored in the actual form template to allow you to manually unprotect and reprotect the form while preserving the form field contents.

The following three macros can be used to ensure that your form field values are not reset to their defaults when you reprotect the form.

The first macro runs when you click the Protect Form button on the Forms toolbar.
The second macro runs when you click either Protect Document or Unprotect Document on the Tools menu.
The third macro allows you to specify which sections to protect while maintaining previous form field values.

Note The name of this macro must be ProtectForm.

Sub ProtectForm()

   ' ******************************************
   ' ProtectForm Macro.
   ' Toggles protection for the active document
   ' when the Protect Form button on the forms
   ' toolbar is clicked.
   ' ******************************************
   If ActiveDocument.ProtectionType = wdNoProtection Then
      ActiveDocument.Protect Type:=wdAllowOnlyFormFields, _
         NoReset:=True
   Else
      ActiveDocument.Unprotect Password:=""
   End If

End Sub

The following sample Visual Basic macro protects the active document without displaying the Protect dialog box. When you run this macro, it reprotects the active document while maintaining previous form field values.

Note The name of this macro must be ToolsProtectUnprotectDocument.

Sub ToolsProtectUnprotectDocument()

   ' ******************************************
   ' ToolsProtectUnprotectDocument Macro
   ' Sets protection for the active document
   ' when Protect Document or Unprotect Document
   ' is clicked on Tools menu
   ' ******************************************
   If ActiveDocument.ProtectionType = wdNoProtection Then
      ActiveDocument.Protect Type:=wdAllowOnlyFormFields, _
         NoReset:=True
   Else
      ActiveDocument.Unprotect Password:=""
   End If

End Sub

The following sample Visual Basic macro allows you to specify which sections to protect while maintaining previous form field values. You can assign this macro to a toolbar button or menu.

Sub ProtectNoReset()

   Dim pDoc As Dialog
   Dim x As Integer
   On Error GoTo ProtectNoResetErr

   ' If the document is protected,
   If ActiveDocument.ProtectionType <> wdNoProtection Then

      ' Unprotect the document.
      ActiveDocument.Unprotect

   End If

   ' Display the Protect Dialog box.
   Set pDoc = Dialogs(wdDialogToolsProtectDocument)
   x = pDoc.Display

   ' If Cancel was chosen, exit this procedure.
   If x = 0 Then Exit Sub

   ' Protect the document.
   ActiveDocument.Protect Password:=pDoc.DocumentPassword, _
      NoReset:=True, Type:=2

ProtectNoResetErr: 'NOTE: This line MUST be left aligned.

If Err <> 0 Then MsgBox Err.Description

End Sub

Method 2: Create a Macro to Protect/Unprotect Your Document

The following examples protect the active document for forms without resetting the contents of the form fields. Create the macro and assign the macro to a key, menu, or toolbar button for easy access.

If ActiveDocument.ProtectionType = wdNoProtection Then
   ActiveDocument.Protect Type:=wdAllowOnlyFormFields, _
      NoReset:=True
End If

Method 3: Unprotect, Check Spelling or Update a Field, Reprotect a Document

Because form field text is formatted for No Proofing, you can use the following macro to:

Temporarily unprotect the form.
Change the language of the form fields.
Perform a spelling check or update a field.
Reprotect the form while preserving the text you've typed into the form fields.

You can use this macro as an On Exit macro for the last form field so you can check the spelling or update a field before you save the form.

Sub FormsSpellCheck()

   ' If document is protected, Unprotect it.
   If ActiveDocument.ProtectionType <> wdNoProtection Then
      ActiveDocument.Unprotect Password:=""
   End If

   ' Set the language for the document.
   Selection.WholeStory
   Selection.LanguageID = wdEnglishUS
   Selection.NoProofing = False

   ' Perform Spelling/Grammar check.
   If Options.CheckGrammarWithSpelling = True Then
      ActiveDocument.CheckGrammar
   Else
      ActiveDocument.CheckSpelling
   End If

   ' ReProtect the document.
   If ActiveDocument.ProtectionType = wdNoProtection Then
      ActiveDocument.Protect Type:=wdAllowOnlyFormFields, _
         NoReset:=True
   End If

End Sub

ImportantThere are some differences in Visual Basic for Applications between Microsoft Word 97 and later versions because of the Enabled Language Settings feature in versions of Microsoft Office that are later than Microsoft Office 97. One of the differences is noted in the previous macro. To correctly check the spelling of a document after you set the LanguageID, you must set the NoProofing property in Word 97 and later versions. However, if you try to run this macro in Microsoft Word 97 for Windows, you will receive the following error message:

Compile error:

Method or data member not found

For additional information about how to do this in Microsoft Word 97 for Windows, click the following article number to view the article in the Microsoft Knowledge Base:

181108 WD97: Form fields lose text when protected for forms

REFERENCES

For additional information about getting help with Visual Basic for Applications, click the following article numbers to view the articles in the Microsoft Knowledge Base:

212623 WD2000: Macro programming resources

305326 List of programming resources for Visual Basic for Applications

226118 List of resources that are available to help you learn Visual Basic for Applications programming

Additional query words: kbmacro vba checkspelling word form field protect spell check spellcheck WD2000

Keywords: kbhowto kbnofix kbprogramming KB191028

Microsoft KB Archive/191028

Contents