Knowledge Base

PPT: Sample Code to Change the Chart Type of a Graph

Article ID: 172836

Article Last Modified on 10/11/2006

APPLIES TO

Microsoft PowerPoint 98 for Macintosh
Microsoft PowerPoint 97 Standard Edition

This article was previously published under Q172836

SUMMARY

This article provides a sample Microsoft Visual Basic for Applications macro (Sub procedure) that creates a Microsoft PowerPoint presentation containing five slides. On each slide, a graph is created using a different chart type, such as pie, column, and so on.

MORE INFORMATION

Microsoft provides programming examples for illustration only, without warranty either expressed or implied. This includes, but is not limited to, the implied warranties of merchantability or fitness for a particular purpose. This article assumes that you are familiar with the programming language that is being demonstrated and with the tools that are used to create and to debug procedures. Microsoft support engineers can help explain the functionality of a particular procedure, but they will not modify these examples to provide added functionality or construct procedures to meet your specific requirements. Before you can run the sample Visual Basic macro, you must add a reference to the Graph 8.0 object model. Follow these steps to add the reference:

On the Tools menu, point to Macros, and then click Visual Basic Editor.
On the Tools menu, click References.
In the "References - VBAProject" dialog box, click to select the "Microsoft Graph 8.0 Object Library" check box.
Click OK.

You now have a reference (in this project) to the Graph 8.0 object model.

Sample Visual Basic Procedure

   Sub ChangeChartType()

      Dim oGraphShape As PowerPoint.Shape
      Dim oGraph As Graph.Chart

      ' Set up an array to hold different chart types.
      Dim lChartTypeArray(1 To 5) As Long

      ' Populate the array with different chart types.
      lChartTypeArray(1) = xl3DPie
      lChartTypeArray(2) = xl3DColumn
      lChartTypeArray(3) = xlBubble3DEffect
      lChartTypeArray(4) = xlPyramidBarStacked
      lChartTypeArray(5) = xlSurfaceTopView

      ' Create a new presentation.
      Dim oPres As PowerPoint.Presentation
      Set oPres = PowerPoint.Presentations.Add

      Dim x As Long
      For x = 1 To 5

         ' Create a new slide.
         oPres.Slides.Add x, ppLayoutBlank

         With oPres.Slides(x)

            ' Create the Graph object.
            Set oGraphShape = .Shapes _
               .AddOLEObject(0,0,oPres.PageSetup.SlideWidth, _
               oPres.PageSetup.SlideHeight, _
               "MSGraph.Chart", _
               Link:=msoFalse)

         End With

         ' Get an object reference to the Graph you just created.
         Set oGraph = oGraphShape.OLEFormat.Object

         ' Set the chart type.
         oGraph.ChartType = lChartTypeArray(x)

         ' Release the reference.
         Set oGraph = Nothing

      Next x

   End Sub

REFERENCES

For more information about creating Visual Basic for Applications macros, click the Office Assistant in Microsoft PowerPoint, type how to create a macro, click Search, and then click to view "Create a macro in Visual Basic Editor."

For more information about running Visual Basic for Applications macros, click the Office Assistant in Microsoft PowerPoint, type how to run a macro, click Search, and then click to view "Run a macro."

NOTE: If the Assistant is hidden, click the Office Assistant button on the Standard toolbar. If the Assistant is not able to answer your query, please see the following article in the Microsoft Knowledge Base:

176476 OFF: Office Assistant Not Answering Visual Basic Questions

For more information about getting help with Visual Basic for Applications, please see the following article in the Microsoft Knowledge Base:

163435 VBA: Programming Resources for Visual Basic for Applications

Additional query words: 8.00 ppt8 vba vbe macppt

Keywords: kbcode kbdtacode kbhowto kbmacro kbprogramming KB172836

Microsoft KB Archive/172836

Contents