Article ID: 121944
Article Last Modified on 10/11/2006
APPLIES TO
- Microsoft Excel 97 Standard Edition
- Microsoft Excel 95 Standard Edition
- Microsoft Excel 5.0 Standard Edition
This article was previously published under Q121944
SUMMARY
Fractions of a degree are commonly expressed in units called minutes and seconds. One degree is equivalent to 60 minutes, and similarly, one minute equals 60 seconds. These units are most commonly used for expressing a navigational point such as a point on a nautical chart.
Although Microsoft Excel lacks a built-in number format to express these terms, this article contains a sample custom function you can use to convert a degree value (stored in decimal format, or base 10) to degrees, minutes, and seconds (stored in text format). Also, this article contains a user-defined function that converts degrees, minutes, and seconds (stored in text format) to a degree value (stored in decimal format).
MORE INFORMATION
Microsoft provides programming examples for illustration only, without warranty either expressed or implied. This includes, but is not limited to, the implied warranties of merchantability or fitness for a particular purpose. This article assumes that you are familiar with the programming language that is being demonstrated and with the tools that are used to create and to debug procedures. Microsoft support engineers can help explain the functionality of a particular procedure, but they will not modify these examples to provide added functionality or construct procedures to meet your specific requirements.
Converting Decimal Degrees to Degrees/Minutes/Seconds
The following Microsoft Visual Basic for Applications custom function accepts an angle formatted as a decimal value and convert it to a text value displayed in degrees, minutes, and seconds.
Function Convert_Degree(Decimal_Deg) As Variant
With Application
'Set degree to Integer of Argument Passed
Degrees = Int(Decimal_Deg)
'Set minutes to 60 times the number to the right
'of the decimal for the variable Decimal_Deg
Minutes = (Decimal_Deg - Degrees) * 60
'Set seconds to 60 times the number to the right of the
'decimal for the variable Minute
Seconds = Format(((Minutes - Int(Minutes)) * 60), "0")
'Returns the Result of degree conversion
'(for example, 10.46 = 10~ 27 ' 36")
Convert_Degree = " " & Degrees & "~ " & Int(Minutes) & "' " _
& Seconds + Chr(34)
End With
End Function
To use this function, create a conversion formula, as in the following example:
=Convert_Degree(10.46)
This formula will return 10~ 27' 36" (that is, 10 degrees, 27 minutes, 36 seconds).
Converting Degrees/Minutes/Seconds to Decimal Degrees
The following Microsoft Visual Basic for Applications custom function accepts a text string of degrees, minutes and seconds formatted in the exact same format that the Convert_Degree function returns (for example, 10~ 27' 36") and converts it to an angle formatted as a decimal value. This is exactly the reverse of the Convert_Degree custom function.
WARNING: This custom function fails if the Degree_Deg argument does not follow the format of the following:
<degrees>~ <minutes>' <seconds>"
as stated earlier.
Function Convert_Decimal(Degree_Deg As String) As Double
' Declare the variables to be double precision floating-point.
Dim degrees As Double
Dim minutes As Double
Dim seconds As Double
' Set degree to value before "~" of Argument Passed.
degrees = Val(Left(Degree_Deg, InStr(1, Degree_Deg, "~") - 1))
' Set minutes to the value between the "~" and the "'"
' of the text string for the variable Degree_Deg divided by
' 60. The Val function converts the text string to a number.
minutes = Val(Mid(Degree_Deg, InStr(1, Degree_Deg, "~") + 2, _
InStr(1, Degree_Deg, "'") - InStr(1, Degree_Deg, _
"~") - 2)) / 60
' Set seconds to the number to the right of "'" that is
' converted to a value and then divided by 3600.
seconds = Val(Mid(Degree_Deg, InStr(1, Degree_Deg, "'") + _
2, Len(Degree_Deg) - InStr(1, Degree_Deg, "'") - 2)) _
/ 3600
Convert_Decimal = degrees + minutes + seconds
End Function
To use this function, create a conversion formula, as in the following example:
=Convert_Degree("10~ 27' 36""")
This formula will return 10.46 (that is, 10.46 degrees).
NOTE: You are required to type three quotation marks (""") at the end of argument of this formula to balance the quotation mark for the seconds and the quotation mark for the text string.
REFERENCES
For additional information about getting help with Visual Basic for Applications, please see the following article in the Microsoft Knowledge Base:
163435 VBA: Programming Resources for Visual Basic for Applications
Additional query words: 5.00a 5.00c 7.00a 97 XL97 XL7 XL5 XL
Keywords: kbdtacode kbhowto kbprogramming KB121944
